La Confrérie des Traducteurs

Code : Tout sélectionner

Begin zRav_respivi_script 

; j'ai nommé tous les objets sous la convention "z<ID>_<effet>_<fonction>"  
; pour les retrouver tous classés en tête de liste en cliquant la colone "ID"

; dans cet algo les blocs "if" s'exécutent en commençant par le dernier, 
; qui détecte le cast dans une première frame,
; pour que la commande à exécuter par le premier s'exécute dans une seconde frame
; ( c'est plus sûr comme ça ).

; on déclare une variable "toggle" 
; dont le dernier bloc "if" va déterminer la valeur au moment du cast du sort
; pour dire aux autres blocs concernés si la capacité est active ou pas 
; ils exécuteront alors ce qu'ils doivent exécuter, c a d l'ajouter au PJ ou la lui retirer :

short toggle 

if menumode ; convention d'économie de fps
	return
endif

; si toggle == 0 aucune commande n'est exécutée, le test passe directement au bloc suivant
if ( toggle == 1 ) ; c a d 0+1 si la capacité est inactive, cf +bas
	Player -> addspell, "zRav_respivi_cap" ; on ajoute la capacité
	set toggle to 0 ; on revient à l'état initial de surveillance du cast
elseif ( toggle == 2 ) ; c à d 1+1 si la capacité est active, cf idem
	Player -> removespell, "zRav_respivi_cap" ; on retire la capacité
	set toggle to 0
endif

if ( Player -> GetSpellEffects, "zRav_respivi_cast" == 1 ) 
; si quand toggle est à 0 le joueur a casté le sort d'activation/désactivation :
	set toggle to ( Player -> GetSpellEffects, "zRav_respivi_cap" )
		; si la capacité est inactive toggle restera à 0 
			; le bloc de tête ne s'exécuterait pas dans la frame suivante
		; si la capacité est active toggle sera écrite à 1
			; le bloc supérieur (ne) l'ajouterait (pas) une seconde fois
		; donc on incrémente de 1 pour activer les blocs dans la prochaine frame :
	set toggle to ( toggle + 1 ) 
endif

end

Code : Tout sélectionner

Begin zzRav_racialcaps

; une variable short de fonction on/off pour chaque race
short toggle_argo 
short toggle_khaj
; la variable en float conventionnelle pour le timer qui va gérer les ajouts de capacité remplaçant les sorts :
float timer

if menumode ; convention d'économie de ressources cpu/mémoire -moins utile aujourd'hui sous multi-coeurs-
	return
endif

; tant que le sort n'a pas été casté, l'exécution des fonctions commencera par le dernier bloc, qui teste ce cast : 
; c'est pour que les blocs qui suivent dans l'ordre logique mais sont là en tête d'écriture s'exécutent dans la frame qui suit le test
; c'est plus sûr comme ça

if ( timer >= 120 ) ; durée vanilla de la respiration aquatique Argonienne
	set toggle_argo to 2 ; on instruit le bloc suivant
elseif ( timer >= 30 ) ; tout idem pour Khajiits
	set toggle_khaj to 2
endif

if ( toggle_argo == 1 ) ; si la capacité argonienne n'est pas active
	Player -> addspell, "zzRav_respira_cap" ; on ajoute la capacité
	set timer to ( timer + GetSecondsPassed ) ; on lance le timer de la durée voulue
elseif ( toggle_argo == 2 ) ; si sort re-casté avant end timer ou si end timer
	set timer to 0
	set toggle_argo to 0
	Player -> removespell, "zzRav_respira_cap" ; on retire la capacité
eleseif ( toggle_khaj == 1 ) ; tout idem Khajiit
	Player -> addspell, "zzRav_visnoc_cap" ; on ajoute la capacité
	set timer to ( timer + GetSecondsPassed )
elseif ( toggle_khaj == 2 )
	set timer to 0
	set toggle_khaj to 0
	Player -> removespell, "zzRav_visnoc_cap"
endif

if ( Player -> GetSpellEffects, "zzRav_respira_spl" == 1 ) ; si le sort on/off Argonien est casté
	set toggle_argo to ( Player->GetSpellEffects, "zzRav_respira_cap" ) ; cap active, ou non?
	set toggle_argo to ( toggle_argo + 1 ) ; instruction blocs prochaine frame
elseif ( Player -> GetSpellEffects, "zzRav_visnoc_spl" == 1 ) ; idem Khajiits
	set toggle_khaj to ( Player -> GetSpellEffects, "zzRav_visnoc_cap" )
	set toggle_khaj to ( toggle_khaj + 1 )
endif

end

Code : Tout sélectionner

begin zzRav_TestRace

; "CharGenState" est la globale Beth dont des incrémentations gèrent
; les étapes de la création de PJ dans les scripts "CharGen[<ID>]" -cf in TESCS-
; et dont la valeur -1 indique sa création achevée, Cosadès ttc inclus. 
; Tout mod de démarrage rapide éventuellement utilisé aura renseigné cette valeur,
; ton mod est compatible.

; "PCRace" est la globale Beth renseignée à valeur de 1 à 10
; au moment du choix de race
; dans l'ordre alphabétique des 10 races jouables (cf la liste dans le tescs
; ou dans le MSFD ou sur l'UESP)
; on ne déclare pas les globales en locales sous peine de conflits-crashs, oeuf corse.
; on n'a besoin d'en déclarer là qu'une seule:

short race

if ( CharGenState > -1 )
	return ; on n'agit pas avant la finalisation de PJ
endif

if ( menumode == 1 )
	return
endif

if ( PCRace == 1 )  ; Argonien
	set race to 1 
	; par soucis d'éventuelle incompatibilité ( cf l'exemple Khajiit ci-dessous ) je remplace les sorts d'origine :
	Player -> removespell "argonian breathing" 
	Player -> addspell "zzRav_respira_spl" 
	startscript, "zzRav_racialcaps"
	return
elseif ( PCRace == 6 ) ; Khajiit
	set race to 1 ; inutile de différencier ici, c'est juste pour le stopscript
	Player -> removespell "eye of night" 
	; au moins un PNJ vanilla utilise ou/et vend ce sort, 
	; pour la CamonaTong je crois
	Player -> addspell "zzRav_visnoc_spl"
	startscript, "zzRav_racialcaps"
	return
else
	set race to 2
	;Player -> addspell "zzRav_visnoc_spl" ; pour test sur partie en cours avec une autre race
	;startscript, "zzRav_racialcaps" ; j'ai mis des " ; " pour désactiver ces lignes, tu peux les retirer pour refaire les tests
	return ; le stopscript ci-dessous s'exécutera dans la frame suivante est + sûr (expérience commune)
endif
;===========================================================
; !!! ATTENTION RÈGLE DE BASE POUR LES "STOPSCRIPT" !!! : 
; il faut d'abord compiler le script et enregistrer l'esp
; une première fois SANS ce dernier bloc entre ========
; (mais sans oublier le "end" qui suit évidemment)
; sinon ce script à stopper ne se  reconnaîtra pas lui-même dans le compilateur où il ne sera pas encore compilé!
; une fois fait, rédiger ou copcol ce bloc puis recompiler/re-enregistrer
; puis placer le script en startscript
 
if ( race > 0 )
	stopscript, "zzRav_TestRace" ; inutile que ça continue à tourner
endif
;============================================================

end

Code : Tout sélectionner

begin zzRav_TestRace

short race

if ( CharGenState > -1 )
	return
endif

if ( menumode == 1 )
	return
endif

if ( PCRace == 1 )
	set race to 1 
	Player -> removespell "argonian breathing" 
	Player -> addspell "zzRav_respira_spl" 
	startscript, "zzRav_racialcaps"
	return
elseif ( PCRace == 6 ) ; Khajiit
	set race to 1 ; inutile de différencier ici, c'est juste pour le stopscript
	Player -> removespell "eye of night" 
	Player -> addspell "zzRav_visnoc_spl"
	startscript, "zzRav_racialcaps"
	return
else
	set race to 2
	return
endif

if ( race > 0 )
	stopscript, "zzRav_TestRace"
endif

end

Code : Tout sélectionner

Begin zzRav_racialcaps

short toggle_argo 
short toggle_khaj
float timer

if menumode
	return
endif

if ( timer >= 120 )
	set toggle_argo to 2
elseif ( timer >= 30 )
	set toggle_khaj to 2
endif

if ( toggle_argo == 1 )
	Player -> addspell, "zzRav_respira_cap"
	set timer to ( timer + GetSecondsPassed )
elseif ( toggle_argo == 2 )
	set timer to 0
	set toggle_argo to 0
	Player -> removespell, "zzRav_respira_cap"
eleseif ( toggle_khaj == 1 )
	Player -> addspell, "zzRav_visnoc_cap"
	set timer to ( timer + GetSecondsPassed )
elseif ( toggle_khaj == 2 )
	set timer to 0
	set toggle_khaj to 0
	Player -> removespell, "zzRav_visnoc_cap"
endif

if ( Player -> GetSpellEffects, "zzRav_respira_spl" == 1 )
	set toggle_argo to ( Player->GetSpellEffects, "zzRav_respira_cap" )
	set toggle_argo to ( toggle_argo + 1 )
elseif ( Player -> GetSpellEffects, "zzRav_visnoc_spl" == 1 )
	set toggle_khaj to ( Player -> GetSpellEffects, "zzRav_visnoc_cap" )
	set toggle_khaj to ( toggle_khaj + 1 )
endif