Poids des munitions/aide/divers v1.0 Fr

[Corax]

Poids des munitions/aide/divers

Version : 1.0

Auteur : AnT01 (AnTone)

Lien VO : http://www.nexusmods.com/fallout3/mods/611

Rubrique de téléchargement : Gameplay

Prérequis : Fallout 3

Description :
Une chose assez bizarre dans Fallout 3, c'est que les munitions n'ont pas de poids, vous trouvez normal d'avoir 2000 balles de 5mm, 1000 de 10mm, 50 nukes, 100 missiles, etc...
Ce mod contient 3 plugins:
> Poids Munitions: Toutes les munitions ont un poids maintenant. (Ce mod ne modifie pas les munitions, il s'agit d'un simple scprit, comme ça ce mod ne rentre pas en conflit avec les autres mods touchant aux munitions)
Darts; BB Ammo; 5mm - 0.01
10mm; .32 Caliber; Electron Charge Pack; Small Energy Cell; Alien Power Cell - 0.03
Railway Spikes; .44 Magnum; .308 Caliber; 5.56mm; Microfusion Cell; Carburant - 0.05
Cartouche Calibre 12; Cellule de Médusatron - 0.1
Missile - 1.0
Mini Nuke - 3.0

> Poids Aide: Les stimpaks et les autres éléments de la section aide ont maintenant un poids. (Si vous utilisez le mod "Bienvenue dans les Terres Désolées", n'activez ce .esp)

> Poids Divers: Donne un poids aux capsules, épingles, doigts, oreilles... (0.1 en général)


Traducteur : Corax
Testeur : Corax

Autorisation : Envoyée

[Dada4]

Tien, je suis en train de modifier le script, pour une "meilleur précision":

Code : Tout sélectionner

scn AmmoWeightScript
Short AWC

Begin GameMode
   set AWC to (Player.GetItemCount AmmoDart)*7							;poids maxi flechette 38grammes
   set AWC to (AWC + (Player.GetItemCount AmmoBB)*1)					;plombs ~ 5 grammes
   set AWC to (AWC + (Player.GetItemCount Ammo5mm)*2)					;munition du Minigun ~ 10 grammes
   set AWC to (AWC + (Player.GetItemCount Ammo10mm)*4)					;.40 S&W 10x25mm ~ 21grammes
   set AWC to (AWC + (Player.GetItemCount Ammo32Caliber)*3)				;7.65x25 ~ 16 grammes
   set AWC to (AWC + (Player.GetItemCount Ammo44magnum)*6)				;44 Magnum ~28 grammes
   set AWC to (AWC + (Player.GetItemCount Ammo308Caliber)*4)			;7.62x51 ~ 20 grammes
   set AWC to (AWC + (Player.GetItemCount Ammo556mm)*2)					;5.56x45 ~ 11 grammes
   set AWC to (AWC + (Player.GetItemCount AmmoShotgunShell)*10)			;Chevrotine 12x76 ~ 50 grammes
   set AWC to (AWC + (Player.GetItemCount AmmoElectronChargePack)*5)	;Pack de charge à électrons
   set AWC to (AWC + (Player.GetItemCount AmmoSmallEnergyCell)*3)		;Cellule énergétique
   set AWC to (AWC + (Player.GetItemCount AmmoAlienPowerCell)*2)		;Cellule alien
   set AWC to (AWC + (Player.GetItemCount AmmoMicroFusionCell)*6)		;Microcellule à fusion
   set AWC to (AWC + (Player.GetItemCount AmmoMesmetronPowerCell)*8)	;Cell. Médusatron
   set AWC to (AWC + (Player.GetItemCount AmmoRailwaySpikes)*20)		;environ 100grammes
   set AWC to (AWC + (Player.GetItemCount AmmoFlamerFuel)*80)			;1/2 litres  ~ 400g
   set AWC to (AWC + (Player.GetItemCount AmmoMissile)+400)				;rocket missile LAW = 1.8 Kgs
   set AWC to (AWC + (Player.GetItemCount ammoFatMan)*600)				;environ 3kgs

   if AWC > (Player.GetItemCount AmmoWeightCounter)
      set AWC to (AWC - Player.GetItemCount AmmoWeightCounter)
      Player.AddItem AmmoWeightCounter AWC 1
   elseif AWC < (Player.GetItemCount AmmoWeightCounter)
      set AWC to (Player.GetItemCount AmmoWeightCounter - AWC)
      Player.RemoveItem AmmoWeightCounter AWC 1
   endif
End

Y'a qu'a remplacer le script original par celui du dessus.
Je testerai ce soir, pour voir si ça fonctionne.(Je vais aussi rajouter le poids des grenades du lance-patates)

[Corax]

Sympa Dada4 mais comme le jeu utilise les lbs, et que tu me donne la valeurs en grammes, dans le jeu cela sera t'il en lbs ou en gr?

[Dada4]

Les grammes c'est pour infos.
Exemple:
set AWC to (AWC + (Player.GetItemCount Ammo308Caliber)*4) ;7.62x51 ~ 20 grammes

poids d'une cartouche 7.62x51 = 20 grammes, dans la formule, c'est 4 ( j'ai arrondis
1 lb pour 0.5 kg , en vrai c'est 1 lb = 0,45 kg) 20/10 ( car le poids de "ammoweightcounter" est en centièmeme de lb)/0.5 = 4 ( plus exactement 0.04 lb)

Si tu regarde dans ARMO et l'objet Ammoweightcounter, tu verra que le poids est de 0.01.

On pourrai facilement exprimer le poids des munition en grammes, par exemple:
set AWC to (AWC + (Player.GetItemCount Ammo308Caliber)*20) ;7.62x51 ~ 20 grammes

et modifier le poids de Ammoweightcounter à 0.0022. Comme ça on aura le résultat final en lb ( car il y aura autant de Ammoweightconter qye de AWC (résltats total des poids des munitions) donc AWC* 0.0022 (poids de l'objet)).

On peu faire comme on veux...

[Firestorm]

J'ai fais un script pour calculer le poids des munitions il y a quelques temps afin de l'utiliser dans mon mod, bon il est moins bien que celui de dada4 car il appelle beaucoup de variables, mais il est plus simple à comprendre donc je vous en fait part.

le script est en grammes, pour tout mettre en livres il suffit de convertir le 1000 par 2204 dans la ligne suivante :

Code : Tout sélectionner

set varnb to (varflingue + varfusil + varassaut + varsnipe + vardiver)*1000

ce qui donnera :

Code : Tout sélectionner

set varnb to (varflingue + varfusil + varassaut + varsnipe + vardiver)*2204

Ce script est très précis car il calcul le poids au gramme près (et non à la dizaine près). De plus convertir les kilos en livres ce fait rapidement (voir ci-dessus), et le poids des cartouches est réaliste.

Code : Tout sélectionner

scn FUzzSCRIPTzzAMMOSzzWEIGHT

;-----------------------------------------------
;FALLOUT ULTIMATUM 2
;Script by Firestorm
;
;http://bethesdamodding.free.fr
;
;Utilisez le à votre guise!
;------------------------------------------------

float var9x19
float var9x18
float var45acp
float var50ae
float var460x30
float var30c
float var3006
float var762x39
float var545x39
float var556x45
float var9x39
float var762x51
float var762x51perfo
float var338
float var762x54
float var127x99
float var127x99perfo
float var40
float var12
float var25
float varmix
float vararba
float varrpg

float varrailway
float varmissile
float var10mm
float var32
float var308
float var44
float varshotgun
float var556
float var5mm
float varfuel
float varfatman

float varflingue
float varfusil
float varassaut
float varsnipe
float vardiver

short varnb


BEGIN gamemode

;----------------------------------------------------------
;Calcul du poids
;

set var9x19 to (0.025*player.getitemcount FUzzAMMOzz9x19)
set var9x18 to (0.022*player.getitemcount FUzzAMMOzz9x18)
set var45acp to (0.030*player.getitemcount FUzzAMMOzz45acp)
set var50ae to (0.150*player.getitemcount FUzzAMMOzz50ae)
set var10mm to (0.022*player.getitemcount Ammo10mm)
set var32 to (0.015*player.getitemcount Ammo32Caliber)
set var44 to (0.027*player.getitemcount Ammo44magnum)

set varflingue to (var9x19 + var9x18 + var45acp + var50ae + var10mm + var32 + var44)

set var460x30 to (0.03*player.getitemcount FUzzAMMOzz46x30)
set var30c to (0.035*player.getitemcount FUzzAMMOzz30c)
set var3006 to (0.035*player.getitemcount FUzzAMMOzz3006)
set var12 to (0.035*player.getitemcount FUzzAMMOzz12)
set varshotgun to (0.035*player.getitemcount AmmoShotgunShell)

set varfusil to (var460x30 + var30c + var3006 + var12 + varshotgun)

set var762x39 to (0.050*player.getitemcount FUzzAMMOzz762x39)
set var545x39 to (0.040*player.getitemcount FUzzAMMOzz545x39)
set var556x45 to (0.045*player.getitemcount FUzzAMMOzz556x45)
set var9x39 to (0.110*player.getitemcount FUzzAMMOzz9x39)
set var762x51 to (0.093*player.getitemcount FUzzAMMOzz762x51)
set var556 to (0.045*player.getitemcount Ammo556mm)

set varassaut to (var762x39 + var545x39 + var556x45 + var9x39 + var762x51 + var556)

set var762x51perfo to (0.093*player.getitemcount FUzzAMMOzz762x51perfo)
set var762x54 to (0.093*player.getitemcount FUzzAMMOzz762x54)
set var338 to (0.093*player.getitemcount FUzzAMMOzz338)
set var127x99 to (0.157*player.getitemcount FUzzAMMOzz127x99)
set var127x99perfo to (0.157*player.getitemcount FUzzAMMOzz127x99perfo)
set var308 to (0.093*player.getitemcount Ammo308Caliber)
set var5mm to (0.157*player.getitemcount Ammo5mm)
set var25 to (0.450*player.getitemcount FUzzAMMOzz25mm)

set varsnipe to (var762x51perfo + var762x54 + var338 + var127x99 + var127x99perfo + var308 + var5mm + var25)

set var40 to (0.5*player.getitemcount Ammo40mm)
set varmissile to (2.5*player.getitemcount AmmoMissile)
set varrpg to (1.5*player.getitemcount FUammoRPG)
set varrailway to (0.05*player.getitemcount AmmoRailwaySpikes)
set varmix to (0.06*player.getitemcount FUzzAMMOzzMIXTE)
set vararba to (0.045*player.getitemcount FUzzAMMOzzARBA)
set varfuel to (player.getitemcount AmmoFlamerFuel)
set varfatman to (2*player.getitemcount ammoFatMan)

set vardiver to (var40 + varmissile + varrailway + varmix + vararba + varfuel)
;
;Fin du calcul
;----------------------------------------------------------

set varnb to (varflingue + varfusil + varassaut + varsnipe + vardiver)*1000

if varnb > (player.getitemcount FuzzITEMzzAMMOSzzWEIGHT)
    set varnb to (varnb - player.getitemcount FuzzITEMzzAMMOSzzWEIGHT)
    player.additem FuzzITEMzzAMMOSzzWEIGHT varnb 1
elseif varnb < (player.getitemcount FuzzITEMzzAMMOSzzWEIGHT)
    set varnb to (player.getitemcount FuzzITEMzzAMMOSzzWEIGHT - varnb)
    player.removeitem FuzzITEMzzAMMOSzzWEIGHT varnb 1
endif


END

[Dada4]

Ah ouai! daccord! ça c'est du scripte , complet et tout.

Bien j'ai testé mon bout de scripte et il marche.

Code : Tout sélectionner

scn AmmoWeightScript
Short AWC

Begin GameMode
   set AWC to (Player.GetItemCount AmmoDart)*38									;poids maxi flechette 38grammes
   set AWC to (AWC + (Player.GetItemCount AmmoBB)*5)							;plombs ~ 5 grammes
   set AWC to (AWC + (Player.GetItemCount Ammo5mm)*10)						;munition du Minigun ~ 10 grammes
   set AWC to (AWC + (Player.GetItemCount Ammo10mm)*21)						;.40 S&W 10x25mm ~ 21grammes
   set AWC to (AWC + (Player.GetItemCount Ammo32Caliber)*16)					;7.65x25 ~ 16 grammes
   set AWC to (AWC + (Player.GetItemCount Ammo44magnum)*28)				;44 Magnum ~28 grammes
   set AWC to (AWC + (Player.GetItemCount Ammo308Caliber)*20)					;7.62x51 ~ 20 grammes
   set AWC to (AWC + (Player.GetItemCount Ammo556mm)*11)						;5.56x45 ~ 11 grammes
   set AWC to (AWC + (Player.GetItemCount AmmoShotgunShell)*50)				;Chevrotine 12x76 ~ 50 grammes
   set AWC to (AWC + (Player.GetItemCount AmmoElectronChargePack)*22)		;Pack de charge à électrons
   set AWC to (AWC + (Player.GetItemCount AmmoSmallEnergyCell)*15)			;Cellule énergétique
   set AWC to (AWC + (Player.GetItemCount AmmoAlienPowerCell)*10)			;Cellule alien
   set AWC to (AWC + (Player.GetItemCount AmmoMicroFusionCell)*30)			;Microcellule à fusion
   set AWC to (AWC + (Player.GetItemCount AmmoMesmetronPowerCell)*40)	;Cell. Médusatron
   set AWC to (AWC + (Player.GetItemCount AmmoRailwaySpikes)*100)			;environ 100grammes
   set AWC to (AWC + (Player.GetItemCount AmmoFlamerFuel)*400)				;1/2 litres  ~ 400g
   set AWC to (AWC + (Player.GetItemCount AmmoMissile)+1800)					;rocket missile LAW = 1.8 Kgs
   set AWC to (AWC + (Player.GetItemCount ammoFatMan)*3000)					;environ 3kgs
   set AWC to (AWC + (Player.GetItemCount a2AmmoGNHE)*280)				;Munition grenade HE  ~ 280g
   set AWC to (AWC + (Player.GetItemCount a3AmmoGNI)*250)				;Munition grenade Incendiaire  ~ 250g
   set AWC to (AWC + (Player.GetItemCount A1AmmoGNaP)*250)				;Munition grenade EMP  ~ 250g
   set AWC to (AWC + (Player.GetItemCount a4AmmoGNPL)*270)				;Munition grenade Plasma  ~ 270
   if AWC > (Player.GetItemCount AmmoWeightCounter)
      set AWC to (AWC - Player.GetItemCount AmmoWeightCounter)
      Player.AddItem AmmoWeightCounter AWC 1
   elseif AWC < (Player.GetItemCount AmmoWeightCounter)
      set AWC to (Player.GetItemCount AmmoWeightCounter - AWC)
      Player.RemoveItem AmmoWeightCounter AWC 1
   endif
End

Avec dans AmmoWeightCounter j'ai mis en Value: 0.0022

Comme ça les grammes sont transformés en lb, compatible avec le poids de Fallout en lb.

[Firestorm]

Non le tien est beaucoup mieux car il n'appelle pas 50 000 variables comme le mien lol! Ça va que le mien marche sinon je pense que je 'aurais piqué le tien lol!

Y a juste un truc que tu pourrais améliorer dans ton script, c'est les données. Exemple une cartouche de 5.56x45mm pèse environ 45grammes en vrai.

Prend les valeurs de mon script (exemple 0.157 = 157grammes), elles sont correctes (merci google lol)

[Corax]

C'est vrai que quand je regarde les 2 scripts, celui de Dada4 est beaucoup plus court. Je ne sais pas si la longueur du script influence sur le jeu?

Sinon je pense que je vais proposer 2 versions pour ce mod.
Une version avec les valeurs réels (le poids des munitions), et une autre avec des valeurs plus faible mais qui laisse un jeu plus jouable.

Donc Dada4, j'ai ton autorisation pour mettre ton scrip à la place de celui de base?

NB: Merci à vous deux, comme ça j'en apprend un peu plus sur les scripts (j'ai réussi à modifier celui de base et celui pour Schémas de Munitions, bon ils sont basiques mais c'est un début)

EDIT: Dada4, si tu m'autorise, tu peux mettre le bon script. (avec les valeurs en lb. Je ne veux pas changer l'unité de poids du jeu). Merci

[Firestorm]

Celui de dada4 est plus court car il n'a pas déclaré de variables, et son script ne porte que sur les munitions du jeu (le mien étant pour le FU il y à de nombreuses munitions supplémentaires à prendre en compte) sinon ce sont sensiblement les mêmes lol.

Pour ton idée de faire 2 versions, il te suffit de faire ce script en 2 exemplaire, sauf que l'un ajoutera l'objet qui pèse 0.0022 et l'autre ajoutera l'objet qui pèse 0.0011 (par exemple) et qui sera la version "easy" lol!

Tu peux faire un menu qui permettra à l'utilisateur de choisir si il veut jouer avec la version normale ou la easy.

Tu peux utiliser le script de menu du FU 2 si tu veux.

Le menu : http://bethesdamodding.free.fr/._files/ ... f/menu.gif

Le script : http://bethesdamodding.free.fr/._files/ ... zzmenu.txt


C'est aussi simple que ça :

Message : Utiliser version Easy ou normale ?

• Action de l'utilisateur : Choix version normale
  • Le script du message démarre la quète "Version Normale"
    • La Quète démarre le script "Version Normale"

ou

• Action de l'utilisateur : Choix version Easy
  • Le script du message démarre la quète "Version Easy"
    • La Quète démarre le script "Version Easy"

[Dada4]

Vous en usez et abusez comme vous le souhaiter. C'est Freeuser.
Par contre je persiste sur e poids de la cartouche 5.56x45 OTAN c'est bien entre 11 et 12 grammes. Je pense que tu confond avec le "grain" une unité batarde anglo-saxonne pour mesurer le poids de la balle ou de la poudre.
(1 gramme = 14,43236 grains).

Wiki est ton ami.

Ouala... et encore merci.